layout* ( gadget -- )
Factor handbook » UI framework » Building user interfaces » Gadget hierarchy and layouts » Implementing layout gadgets

Next:

pref-dim ( gadget -- dim )

Vocabulary
ui.gadgets

Inputs

gadget

a gadget

Outputs
None

Generic word contract
Lays out the children of the gadget according to the gadget's policy. The dimensions of the gadget are already set by the parent by the time this word is called.

Notes
User code should not call this word directly, instead call relayout and relayout-1.

See also
pref-dim, pref-dim*, layout

Definition

IN: ui.gadgets

GENERIC: layout* ( gadget -- )

Methods

USING: images.viewer.scaling kernel ui.gadgets ;

M: autoscaling-image-gadget layout* pref-dim drop ;


USING: accessors kernel sequences ui.gadgets ui.gadgets.books ;

M: book layout*
    [ children>> ] [ dim>> ] bi [ >>dim drop ] curry each ;


USING: kernel math.rectangles ui.gadgets ui.gadgets.borders
ui.gadgets.borders.private ;

M: border layout*
    [ border-child-rect ] [ gadget-child ] bi set-rect-bounds ;


USING: ui.gadgets ui.gadgets.sliders.private ;

M: elevator layout* find-slider layout-thumb ;


USING: accessors kernel math opengl sequences ui.gadgets
ui.gadgets.frame-buffer ;

M:: frame-buffer layout* ( FRAME-BUFFER -- )
    FRAME-BUFFER last-dim>> [
        FRAME-BUFFER dim>> = [
            FRAME-BUFFER pixels>> :> OLD-PIXELS FRAME-BUFFER
            last-dim>> first gl-scale >fixnum :> OLD-WIDTH
            FRAME-BUFFER init-frame-buffer-pixels FRAME-BUFFER
            [ dim>> ] [ last-dim<< ] bi
            FRAME-BUFFER pixels>> :> NEW-PIXELS FRAME-BUFFER
            last-dim>> first gl-scale >fixnum :> NEW-WIDTH
            OLD-PIXELS OLD-WIDTH NEW-PIXELS NEW-WIDTH
            copy-pixels
        ] unless
    ] [
        FRAME-BUFFER init-frame-buffer-pixels FRAME-BUFFER
        [ dim>> ] [ last-dim<< ] bi
    ] if* ;


USING: accessors kernel ui.gadgets ui.gadgets.frames
ui.gadgets.frames.private ui.gadgets.grids.private ;

M: frame layout* [ grid>> ] [ <frame-layout> ] bi layout-grid ;


USING: accessors kernel math.rectangles
math.rectangles.positioning ui.gadgets ui.gadgets.glass.private
ui.gadgets.worlds ;

M: glass layout*
    [
        [ visible-rect ] [ gadget-child pref-dim ]
        [ find-world dim>> ] tri popup-rect
    ] [ gadget-child ] bi set-rect-bounds ;


USING: accessors kernel ui.gadgets ui.gadgets.grids
ui.gadgets.grids.private ;

M: grid layout* [ grid>> ] [ <grid-layout> ] bi layout-grid ;


USING: maze ui.gadgets ui.gadgets.canvas ;

M: maze layout* delete-canvas-dlist ;


USING: kernel ui.gadgets ;

M: object layout* drop ;


USING: accessors kernel ui.gadgets ui.gadgets.packs ;

M: pack layout* dup children>> pref-dims pack-layout ;


USING: accessors kernel sequences ui.gadgets
ui.gadgets.paragraphs ui.gadgets.paragraphs.private ;

M: paragraph layout*
    f >>wrapped cached-wrapped dup line-y-coordinates
    [ layout-line ] 2each ;


USING: accessors combinators generic kernel ui.gadgets
ui.gadgets.private ui.gadgets.scrollers
ui.gadgets.scrollers.private ;

M: scroller layout*
    {
        [ M\ scroller layout* (call-next-method) ]
        [
            dup follows>>
            [ update-scroller ] [ >>follows drop ] 2bi
        ]
        [ [ x>> ] [ y>> ] bi [ forget-pref-dim ] bi@ ]
        [ M\ scroller layout* (call-next-method) ]
    } cleave ;


USING: kernel ui.gadgets ui.gadgets.tables
ui.gadgets.tables.private ;

M: table layout*
    [ update-cached-widths ] [ update-filled-column ] bi ;


USING: accessors classes generic kernel ui ui.gadgets
ui.tools.common ;

M: tool layout*
    [ M\ tool layout* (call-next-method) ] [
        dup fullscreen?
        [ drop ] [ [ class-of ] [ dim>> ] bi set-tool-dim ] if
    ] bi ;


USING: kernel ui.gadgets ui.gadgets.packs ui.gadgets.tracks
ui.gadgets.tracks.private ;

M: track layout* dup track-layout pack-layout ;


USING: accessors kernel math.vectors ui.gadgets
ui.gadgets.viewports ;

M: viewport layout*
    [ gadget-child ]
    [ [ dim>> ] [ gadget-child pref-dim ] bi vmax ] bi >>dim
    drop ;


USING: accessors generic kernel sequences ui.gadgets
ui.gadgets.worlds ;

M: world layout*
    [ M\ world layout* (call-next-method) ]
    [ dup layers>> [ as-big-as-possible ] with each ] bi ;


USING: accessors kernel ui.gadgets ui.gadgets.wrappers ;

M: wrapper layout* [ gadget-child ] [ dim>> ] bi >>dim drop ;