resolve-host ( addrspec -- seq )
Networking » Address specifiers

Prev:

<inet6> ( host port -- inet6 )

Vocabulary
io.sockets

Inputs

addrspec

an address specifier

Outputs

seq	a sequence of address specifiers

Word description
Resolves host names to IP addresses.

Errors
Throws an addrinfo-error if the host name cannot be resolved.

Examples

"www.facebook.com" resolve-host . { T{ ipv4 { host "31.13.64.32" } } }

Definition

IN: io.sockets

GENERIC: resolve-host ( addrspec -- seq )

Methods

USING: io.sockets kernel ;

M: f resolve-host drop resolve-localhost ;


USING: accessors io.sockets ;

M: hostname resolve-host host>> resolve-host ;


USING: arrays io.sockets io.sockets.icmp ;

M: icmp4 resolve-host 1array ;


USING: arrays io.sockets io.sockets.icmp ;

M: icmp6 resolve-host 1array ;


USING: generic io.sockets io.sockets.icmp
io.sockets.icmp.private sequences ;

M: icmp resolve-host
    M\ icmp resolve-host (call-next-method) [ with-icmp ] map ;


USING: arrays io.sockets ;

M: inet4 resolve-host 1array ;


USING: arrays io.sockets ;

M: inet6 resolve-host 1array ;


USING: accessors generic io.sockets kernel sequences ;

M: inet resolve-host
    [ M\ inet resolve-host (call-next-method) ] [ port>> ] bi
    [ with-port ] curry map ;


USING: arrays io.sockets ;

M: local resolve-host 1array ;


USING: accessors io.sockets io.sockets.secure kernel sequences ;

M: secure resolve-host
    [ addrspec>> resolve-host ] [ hostname>> ] bi
    [ <secure> ] curry map ;


USING: alien.c-types alien.data classes.struct io.sockets
io.sockets.private kernel math strings unix.ffi ;

M:: string resolve-host ( host -- seq )
    host f prepare-addrinfo f void* <ref> [
        getaddrinfo
        [ dup addrinfo-error-string host addrinfo-error ]
        unless-zero
    ] keep void* deref addrinfo memory>struct
    [ parse-addrinfo-list ] keep freeaddrinfo ;