stream-write ( data stream -- )
Factor handbook » Input and output » Streams » Stream protocol

Prev:	stream-write1 ( elt stream -- )
Next:	stream-nl ( stream -- )

Vocabulary
io

Inputs

data	binary data or a string
stream	an output stream

Outputs
None

Generic word contract
Writes a piece of data to the stream. If the stream performs buffering, output may not be performed immediately; use stream-flush to force output.

Notes
Most code only works on one stream at a time and should instead use write; see Default input and output streams.

Errors
Throws an error if the I/O operation fails.

Definition

IN: io

GENERIC: stream-write ( data stream -- )

Methods

USING: alien byte-arrays byte-vectors io kernel libc math
sequences ;

M: byte-vector stream-write
    over byte-array?
    [ push-all ] [
        2dup [ byte-length ] bi@ 3dup + swap lengthen
        [ tail-slice swap ] curry dip memcpy
    ] if ;


USING: accessors alien destructors io io.streams.c kernel ;

M: c-writer stream-write
    check-disposed [ binary-object ] [ handle>> ] bi* fwrite ;


USING: accessors io io.streams.counting kernel math sequences ;

M:: counting-stream stream-write ( data stream -- )
    data stream stream>> stream-write stream
    [ data length + ] change-out-count drop ;


USING: accessors io io.crlf kernel ;

M: crlf-stream stream-write
    [ underlying>> ] call \ stream-write execute ;


USING: curses curses.listener io kernel ;

M: curses-listener-stream stream-write drop cwrite ;


USING: accessors io io.streams.duplex kernel ;

M: duplex-stream stream-write
    [ out>> ] call \ stream-write execute ;


USING: io io.encodings io.encodings.private ;

M: encoder stream-write >encoder< encode-string ; inline


USING: io kernel ;

M: f stream-write 2drop ; inline


USING: accessors io io.styles kernel ;

M: filter-writer stream-write
    [ stream>> ] call \ stream-write execute ;


USING: growable io sequences ;

M: growable stream-write push-all ;


USING: html.streams html.streams.private io ;

M: html-writer stream-write [ ] emit-html ;


USING: io io.streams.null kernel ;

M: null-writer stream-write 2drop ;


USING: alien destructors io io.ports io.ports.private kernel
math ;

M: output-port stream-write
    [ dup byte-length integer>fixnum-strict ] dip
    check-disposed 0 port-write ;


USING: io kernel sequences ;

M: output-stream stream-write [ stream-write1 ] curry each ;
    inline


USING: io kernel ui.gadgets.panes ui.gadgets.panes.private ;

M: pane-stream stream-write
    [ [ pane-write ] curry split-pane ] do-pane-stream ;


USING: accessors io kernel pdf.streams pdf.streams.private
sequences ;

M: pdf-writer stream-write
    [ f string>texts ] [ data>> ] bi* push-all ;


USING: accessors io io.streams.peek ;

M: peek-stream stream-write stream>> stream-write ;


USING: accessors io io.styles kernel ;

M: style-stream stream-write
    [ style>> ] [ stream>> ] bi stream-format ;