number>text ( n -- str )

Vocabulary

math.text.english

Inputs

n	an integer

Outputs

str

a string

Generic word contract

Converts an integer to a text string representation in English, including appropriate punctuation and conjunctions.

Examples

USING: math.text.english prettyprint ; 12345 number>text .
"twelve thousand, three hundred and forty-five"

Definition

IN: math.text.english

GENERIC: number>text ( n -- str )

Methods

USING: kernel math math.text.english sequences ;

M: complex number>text
    >rect
    [ number>text ] [
        [ 0 < " minus " " plus " ? ]
        [ abs number>text " i" append ] bi
    ] bi* 3append ;


USING: combinators kernel math math.parser math.text.english
math.text.english.private sequences splitting ;

M: float number>text
    {
        { 1/0. [ "infinity" ] }
        { -1/0. [ "negative infinity" ] }
        [
            dup fp-nan?
            [ drop "not a number" ] [
                number>string "-" ?head swap "e-" split1 [
                    [ 46 swap remove ] dip string>number 1 -
                    48 <repetition> prepend "0" swap
                ] [
                    "e+" split1 [
                        ~quotation~ dip string>number swap -
                        48 <repetition> append "0"
                    ] [ "." split1 ] if*
                ] if* [ string>number number>text ] dip
                [ 48 - small-numbers ] { } map-as
                join-words " point " glue swap
                [ "negative " prepend ] when
            ] if
        ]
    } case ;


USING: math math.text.english math.text.english.private
namespaces ;

M: integer number>text
    [ "zero" ] [ [ (number>text) ] with-scope ] if-zero ;


USING: kernel math math.text.english sequences ;

M: ratio number>text
    >fraction [ number>text ] bi@ " divided by " glue ;