box ( vregs reps c-type -- dst )

Vocabulary

compiler.cfg.builder.alien.boxing

Inputs

vregs	a one-element sequence containing a virtual register indentifier
reps	a one-element sequence containing a representation symbol
c-type	a c-type

Outputs

dst

box

Word description

Emits a ##box-alien instruction which boxes an alien value contained in the given register.

Examples

USING: compiler.cfg.builder.alien.boxing make prettyprint ; { 71 } { int-rep } void* base-type [ box ] { } make nip .
{ T{ ##box-alien { dst 105 } { src 71 } { temp 104 } } }

See also

##box-alien

Definition

IN: compiler.cfg.builder.alien.boxing

GENERIC: box ( vregs reps c-type -- dst )

Methods

USING: accessors alien.c-types combinators
compiler.cfg.builder.alien.boxing compiler.cfg.hats
compiler.cfg.instructions kernel sequences ;

M: c-type box
    [ [ first ] bi@ ] [ boxer>> ] bi* {
        { "from_float" [ drop ] }
        { "from_double" [ drop ] }
        { "from_signed_1" [ drop char ^^convert-integer ] }
        { "from_unsigned_1" [ drop uchar ^^convert-integer ] }
        { "from_signed_2" [ drop short ^^convert-integer ] }
        { "from_unsigned_2" [ drop ushort ^^convert-integer ] }
        { "from_signed_4" [ drop int ^^convert-integer ] }
        { "from_unsigned_4" [ drop uint ^^convert-integer ] }
        { "allot_alien" [ drop ^^box-alien ] }
        [ swap <gc-map> ^^box ]
    } case ;


USING: accessors alien.c-types compiler.cfg.builder.alien.boxing
compiler.cfg.hats compiler.cfg.instructions kernel sequences ;

M: long-long-type box
    [ first2 ] [ drop ] [ boxer>> ] tri*
    <gc-map> ^^box-long-long ;


USING: alien.c-types classes.struct
compiler.cfg.builder.alien.boxing compiler.cfg.hats
compiler.cfg.intrinsics.allot kernel ;

M: struct-c-type box
    [ heap-size ^^allot-byte-array dup ^^unbox-byte-array ]
    curry 2dip implode-struct ;