(compile) ( peg -- quot )

Vocabulary

peg

Inputs

peg

an object

Outputs

quot

an object

Definition

IN: peg

GENERIC: (compile) ( peg -- quot )

Methods

USING: accessors kernel peg peg.private ;

M: action-parser (compile)
    [ parser>> compile-parser-quot ] [ quot>> ] bi
    [ check-action ] curry compose ;


USING: accessors combinators peg peg.private ;

M: box-parser (compile)
    quot>> ( -- parser ) call-effect compile-parser-quot ;


USING: accessors combinators.short-circuit kernel peg
peg.private ;

M: choice-parser (compile)
    parsers>> compile-parsers-quots [ 0|| ] curry ;


USING: accessors assocs kernel namespaces peg peg.private
quotations words ;

M: delay-parser (compile)
    quot>> gensym [ delayed get set-at ] keep 1quotation ;


USING: accessors kernel peg peg.private ;

M: ensure-not-parser (compile)
    parser>> compile-parser-quot [ [ input-slice ] ] dip
    [ check-ensure-not ] compose compose ;


USING: accessors kernel peg peg.private ;

M: ensure-parser (compile)
    parser>> compile-parser-quot [ [ input-slice ] ] dip
    [ check-ensure ] compose compose ;


USING: accessors kernel peg peg.parsers sequences ;

M: just-parser (compile)
    p1>> compile-parser-quot
    [ dup [ dup remaining>> empty? [ drop f ] unless ] when ]
    compose ;


USING: accessors kernel peg peg.private ;

M: optional-parser (compile)
    parser>> compile-parser-quot [ check-optional ] compose ;


USING: accessors kernel peg peg.private ;

M: range-parser (compile)
    [ min>> ] [ max>> ] bi [ [ [ input-slice ] ] dip ] dip
    [ parse-range ] 2curry compose ;


USING: accessors kernel peg peg.private ;

M: repeat0-parser (compile)
    parser>> compile-parser-quot
    [ [ input-slice V{ } clone <parse-result> ] ] dip
    [ swap (repeat) ] curry compose ;


USING: accessors kernel peg peg.private ;

M: repeat1-parser (compile)
    parser>> compile-parser-quot
    [ [ input-slice V{ } clone <parse-result> ] ] dip
    [ swap (repeat) repeat1-empty-check ] curry compose ;


USING: accessors kernel peg peg.private ;

M: satisfy-parser (compile)
    quot>> [ [ input-slice ] ] dip [ parse-satisfy ] curry
    compose ;


USING: accessors kernel peg peg.private ;

M: semantic-parser (compile)
    [ parser>> compile-parser-quot ] [ quot>> ] bi
    [ check-semantic ] curry compose ;


USING: accessors combinators.short-circuit kernel peg
peg.private sequences ;

M: seq-parser (compile)
    parsers>> compile-parsers-quots
    [ [ parse-seq-element ] curry ] map
    [ [ input-slice V{ } clone <parse-result> ] ] dip
    [ 1&& ] curry compose ;


USING: accessors kernel namespaces peg peg.private sequences
unicode ;

M: sp-parser (compile)
    parser>> compile-parser-quot [
        [
            input-slice [ blank? ] trim-head-slice
            input-from pos set
        ]
    ] dip compose ;


USING: accessors kernel peg peg.private ;

M: token-parser (compile)
    symbol>> [ [ input-slice ] ] dip [ parse-token ] curry
    compose ;