decode-char ( stream encoding -- char/f )
Factor handbook » Input and output » I/O encodings » Encoding protocol

Prev:	<decoder> ( stream encoding -- newstream )
Next:	encode-char ( char stream encoding -- )

Vocabulary
io.encodings

Inputs

stream	an underlying input stream
encoding	An encoding descriptor tuple

Outputs

char/f

a code point or f

Generic word contract
Reads a single code point from the underlying stream, interpreting it by the encoding. Returns f if the stream end is reached.

Notes
Calling this word directly is not necessary in most cases. Higher-level words call it automatically.

See also
encode-char

Definition

IN: io.encodings

GENERIC: decode-char ( stream encoding -- char/f )

Methods

USING: accessors io io.encodings io.encodings.8-bit.private
kernel sequences ;

M: 8-bit decode-char
    swap stream-read1
    [ swap from>> ?nth [ replacement-char ] unless* ] [ drop f ]
    if* ;


USING: io io.encodings io.encodings.ascii kernel math ;

M: ascii decode-char
    drop stream-read1 dup
    [ dup 127 <= [ >fixnum ] [ drop replacement-char ] if ] when
    ; inline


USING: accessors assocs combinators io io.encodings
io.encodings.euc io.encodings.euc.private kernel ;

M:: euc decode-char ( stream encoding -- char/f )
    stream stream-read1 {
        { [ dup not ] [ drop f ] }
        {
            [ dup euc-multibyte? ]
            [ stream encoding decode-multibyte ]
        }
        [ encoding table>> at ]
    } cond ;


USING: ascii assocs byte-arrays combinators io io.encodings
io.encodings.gb18030 io.encodings.gb18030.private kernel
namespaces ;

M: gb18030 decode-char
    drop dup stream-read1 {
        { [ dup not ] [ 2drop f ] }
        {
            [ dup ascii? ]
            [ nip 1byte-array mapping get-global value-at ]
        }
        { [ dup quad-1/3? ] [ two-byte ] }
        [ 2drop replacement-char ]
    } cond ;


USING: accessors byte-arrays combinators endian io io.encodings
io.encodings.iso2022.private kernel ;

M:: iso2022-state decode-char ( stream encoding -- char/f )
    stream stream-read1 {
        {
            22
            [
                stream read-escape
                [ encoding type<< stream encoding decode-char ]
                [ replacement-char ] if*
            ]
        }
        { f [ f ] }
        [
            encoding type>> double-width? [
                stream stream-read1
                [ 2byte-array be> encoding finish-decode ]
                [ drop replacement-char ] if*
            ] [ encoding finish-decode ] if
        ]
    } case ;


USING: arrays endian io io.encodings
io.encodings.shift-jis.private kernel ;

M: jis decode-char
    swap dup stream-read1 [
        dup small?
        [ nip swap jis>ch ] [
            swap stream-read1
            [ 2array be> swap jis>ch ]
            [ 2drop replacement-char ] if*
        ] if
    ] [ 2drop f ] if* ;


USING: io io.encodings io.encodings.latin1 kernel math ;

M: latin1 decode-char
    drop stream-read1
    [ dup 256 < [ drop replacement-char ] unless ] [ f ] if* ;


USING: accessors io.encodings io.encodings.strict kernel ;

M: strict-state decode-char
    code>> decode-char dup replacement-char =
    [ decode-error ] when ;


USING: io io.encodings io.encodings.utf16
io.encodings.utf16.private kernel ;

M: utf16be decode-char
    drop dup stream-read1 dup [ begin-utf16be ] when nip ;


USING: io io.encodings io.encodings.utf16
io.encodings.utf16.private kernel ;

M: utf16le decode-char
    drop dup stream-read1 dup [ begin-utf16le ] when nip ;


USING: endian io.encodings io.encodings.utf32
io.encodings.utf32.private kernel ;

M: utf32be decode-char drop [ be> ] char> ;


USING: endian io.encodings io.encodings.utf32
io.encodings.utf32.private kernel ;

M: utf32le decode-char drop [ le> ] char> ;


USING: accessors io io.encodings io.encodings.utf7 kernel ;

M: utf7codec decode-char
    swap [
        [ dialect>> ] [ buffer>> ] bi [ emit-char ] keep
        replace-all!
    ] with-input-stream ;


USING: io.encodings io.encodings.utf8 io.encodings.utf8.private
kernel ;

M: utf8 decode-char drop decode-utf8 ; inline